FC2ブログ
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。
何やかんや Lame用バッチファイル

何やかんや

スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

Lame用バッチファイル

lame.bat

@ECHO OFF
SETLOCAL
SET LameDir=%~dp0
IF "%~1"=="" GOTO MES1
IF NOT EXIST "%LameDir%lame.exe" GOTO MES2
:LOOP
IF /i "%~x1"==".wav" (GOTO CONV) ELSE GOTO SKIP
:CONV
"%LameDir%lame.exe" -V 0 --id3v2-only --pad-id3v2 %1 "%~dpn1.mp3"
SHIFT
IF "%~1"=="" GOTO MES3
GOTO LOOP
:SKIP
ECHO "%~1"は非対応ファイルです
ECHO 続行するには何かキーを押してください . . .(Ctrl + C で強制終了)
PAUSE > nul
SHIFT
IF "%~1"=="" GOTO MES3
GOTO LOOP
:MES1
ECHO 変換したいファイルをバッチファイルにD^&Dして下さい
GOTO END
:MES2
ECHO lame.exeが見つかりません(バッチファイルはlame.exeと同じディレクトリに置いて下さい)
GOTO END
:MES3
ECHO 処理完了
:END
ENDLOCAL
ECHO 何かキーを押すと終了します . . .
PAUSE > nul


上の内容をメモ帳などでコピペして拡張子を「.bat」、文字コードを「ANSI」や「Shift-JIS」で保存。
(文字コードをUnicode等で保存するとコマンドプロンプトの画面で日本語が文字化けする)
保存したファイル(バッチファイル)を lame.exe と同じディレクトリに置き、
デスクトップとかにバッチファイルのショートカットを作成する。
ショートカットにWAVEファイルをD&DするとWAVEファイルと同じ場所にMP3ファイルが出力される。

FC2Ad

上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。